# Maintainer: Cory Sanin <corysanin@artixlinux.org>
# Contributor: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86

pkgname=vivaldi
_rpmversion=7.6.3797.63-1
pkgver=7.6.3797.63
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind.'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('x86_64')
depends=(
    'alsa-lib'
    'at-spi2-core'
    'cairo'
    'libcups'
    'libxss'
    'nss'
    'pango'
    'ttf-font'
    'desktop-file-utils'
    'shared-mime-info'
    'hicolor-icon-theme'
)
makedepends=('w3m')
optdepends=(
    'vivaldi-ffmpeg-codecs: playback of proprietary video/audio'
    'org.freedesktop.secrets: better secret storage in gnome-keyring or kwallet'
    'libnotify: native notifications'
    'pipewire: WebRTC desktop sharing under Wayland'
    'gtk3: gtk3 integration'
    'gtk4: for use with --gtk-version=4'
    'qt5-base: qt5 integration'
    'qt6-base: qt6 integration'
    'upower: Battery Status API support'
)
source=("https://downloads.vivaldi.com/stable/vivaldi-stable-${_rpmversion}.x86_64.rpm"
        '0001-add-support-for-user-flags.patch')
sha512sums=('679e42738c50fe48a14106bd4b4e44e5400715136f1f8f91277f7dd6b99c4b775f37013cd9af2b35d0b5a97d2a283ea47f876ec3f3c39595135b375cefd21a4b'
            'a9bdab0fb0f394af17d1b126bae2d0cdc55e63eaa6eaf36eb994735047d3d7bc5000d75ab930f74b76b283c5addefbd4e4e63c5e4f2908bd53c270e73641c19d')

package() {
    cp --parents -a {opt,usr/bin,usr/share} "$pkgdir"

    # add support for ~/.config/vivaldi-stable.conf
    patch -p1 -i "$srcdir/0001-add-support-for-user-flags.patch" \
        "$pkgdir/opt/$pkgname/$pkgname"
    # remove "orig" leftover if it is there
    rm -f "$pkgdir/opt/$pkgname/$pkgname.orig"

    # suid sandbox
    chmod 4755 "$pkgdir/opt/$pkgname/vivaldi-sandbox"

    install -dm755 "$pkgdir/usr/bin"

    # make /usr/bin/vivaldi-stable available
    binf="$pkgdir/usr/bin/vivaldi-stable"
    if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
        ln -s /opt/vivaldi/vivaldi "$binf"
    fi
    # make /usr/bin/vivaldi available
    binf="$pkgdir/usr/bin/vivaldi"
    if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
        ln -s /opt/vivaldi/vivaldi "$binf"
    fi

    # Vivaldi has different design for each size of icons. Avoid using them.
    install -d "$pkgdir/usr/share/pixmaps"
    # TEMP hack, should be properly provided icon
    ln -sf /opt/${pkgname}/resources/${pkgname}/resources/welcomepage-vivaldi.svg "$pkgdir/usr/share/pixmaps/${pkgname}.svg"
    ln -sf /opt/${pkgname}/product_logo_256.png "$pkgdir/usr/share/pixmaps/${pkgname}.png"

    # license
    install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
    w3m -dump "$pkgdir/opt/$pkgname/LICENSE.html" \
        | head -n 5 \
        > "$pkgdir/usr/share/licenses/$pkgname/license.txt"

    # https://archlinux.org/todo/legacy-path-for-metainfo-files/
    install -Dm644 "usr/share/appdata/$pkgname.appdata.xml" -t \
        "$pkgdir/usr/share/metainfo/"
    rm -rv "$pkgdir/usr/share/appdata"
}